home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs03.d81
/
ba_v6_2.sda
/
MODIFICATIONS
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2009-10-10
|
12KB
|
339 lines
5 CLR:DIMSP$(25),LN(25,3),LN$(25),G$(25),NS$(25)
10 POKE788,52:POKE792,193
14 MT$="[147][154] BANK ACCOUNTS MODIFICATIONS "
15 OPEN15,8,15:POKE53280,0:POKE53281,0:GOSUB1160:GOSUB1365
20 SP$=" "
25 M$(1)="DATE":M$(2)="NUMERIC AMOUNT":M$(4)="LONGHAND AMOUNT":M$(5)="PAYEE"
30 M$(8)="CHECK MEMO"
31 K$="[158] USE UP [158][146] OR DOWN [158][146] TO CHOOSE :"
32 DN$="":UP$="[145]":S7$=" "
33 R$="[158] PRESS RETURN [146][158] TO ENTER SELECTION.[145]"
35 SL$(1)=" CHANGE PASSWORD "
40 SL$(3)=" CHECKPRINTING ON/OFF "
45 SL$(2)=" QUICKLOAD DISABLED "
50 IFQL$="Y"THENSL$(2)=" QUICKLOAD ENABLED "
55 SL$(4)=" MODIFY CHECKPRINTING "
60 SL$(5)=" MODIFY DEFAULT PROMPTS "
65 SL$(6)=" SAVE MODIFICATIONS "
70 SL$(7)=" RETURN TO ENTRY MENU "
95 C1$="":C2$="[154]":C3$="[145][145][145][145][145][145][145][145][145][145][145][145][145]":C4$="":C5$="":MN=7
100 PRINTMT$:MU=1:GOTO110
105 ONANGOTO1435,1600,1610,1500,1250,1050,1120
110 PRINTK$"[145]":POKE198,0:AN=1
115 FORX=1TOMN:PRINTDN$;S7$;C1$;SL$(X):NEXTX
120 PRINTR$:PRINT"";C5$;S7$;C2$;SL$(1)
125 GETAN$:IFAN$<>""THEN155
130 JV=PEEK(56320):FR=JVAND16:JV=15-(JVAND15)
135 IFJV=1THENAN$=CHR$(145):FORT=1TO30:NEXTT:GOTO155
140 IFJV=2THENAN$=CHR$(17):FORT=1TO30:NEXTT:GOTO155
145 IFFR<>16THENAN$=CHR$(13):FORT=1TO30:NEXTT:GOTO155
150 GOTO125
155 IFAN$=CHR$(13)THENAN$=STR$(AN):GOTO171
160 IFAN$=CHR$(145)ORAN$=CHR$(29)THEN175
165 IFAN$=CHR$(17)THEN195
170 GOTO125
171 IFMU=2THEN1540
172 GOTO105
175 LN=AN:AN=AN-1:IFAN=0THENAN=MN
180 PRINT"[145]";S7$;C1$;SL$(LN)
185 IFLN=1THENPRINTC4$;S7$;C2$;SL$(AN):GOTO125
190 PRINTUP$;"[145][145]";S7$;C2$;SL$(AN):GOTO125
195 LN=AN:AN=AN+1:IFAN=MN+1THENAN=1
200 PRINT"[145]";S7$;C1$;SL$(LN)
205 IFLN=MNTHENPRINTC3$;S7$;C2$;SL$(AN):GOTO125
210 PRINTDN$;S7$;C2$;SL$(AN):GOTO125
215 PRINT"[147] THIS OPTION IS DESIGNED TO ALLOW"
220 PRINT"YOU TO CUSTOMIZE THE CHECK PRINTING"
225 PRINT"FORMAT OF THE [154] BANK ACCOUNTS [146] PROGRAM."
230 PRINT" AS INITIALLY PROVIDED, BANK ACCOUNTS"
235 PRINT"IS SET UP TO PRINT ON THE PERSONAL SIZED"
240 PRINT"CHECKS MENTIONED IN THE PROGRAM INFO."
245 PRINT" IF YOU CHOOSE TO USE ANOTHER TYPE OF"
250 PRINT"CHECK, USE THIS OPTION TO MODIFY THE"
255 PRINT"PRINTING POSITIONS FOR THE INFORMATION"
260 PRINT"PRINTED BY BANK ACCOUNTS, TO FIT THE"
265 PRINT"LAYOUT OF THE CHECKS YOU WILL BE USING."
270 PRINT"[158] (PRESS ANY KEY TO CONTINUE)[145]":POKE198,0
275 GETAN$:IFAN$=""THEN275
280 PRINT"[147] FIRST, [154] PRINT AN OVERLAY PATTERN [146],"
285 PRINT"PREPARING YOUR PRINTER AS YOU WOULD IF"
290 PRINT"PRINTING YOUR CHECKS (FONT, NLC, ETC.)."
295 PRINT"THEN MARK THE OVERLAY'S + AT EACH SPOT"
300 PRINT"THAT YOU WANT BANK ACCOUNTS TO PRINT"
305 PRINT"ONE OF IT'S FIVE INFORMATION FIELDS:"
310 PRINT"DATE, NUMERIC AMOUNT, LONGHAND AMOUNT,"
315 PRINT"PAYEE, AND THE CHECK MEMO (ACCT. #)."
320 PRINT"DO THIS BY EITHER TAPING YOUR CHECK ON"
325 PRINT"TOP OF THE OVERLAY & POKING A PIN THRU,"
330 PRINT"OR TAPE THE CHECK UNDER THE OVERLAY AND"
335 PRINT"HOLD UP TO A BRIGHT LIGHT TO MARK IT."
340 PRINT"[158] (PRESS ANY KEY TO CONTINUE)[145]":POKE198,0
345 GETAN$:IFAN$=""THEN345
350 PRINT"[147] ALIGN THE CHECK IN THE UPPER-LEFT"
355 PRINT"CORNER OF THE OVERLAY COVERING THE +'S."
360 PRINT"MARK THE [154]LEFT-MOST POSITION OF WHERE YOU"
365 PRINT"WANT EACH INFORMATION FIELD TO PRINT."
370 PRINT"(NOTE: LOCATION OF THE OPTIONAL ADDRESS"
375 PRINT"AND THE TOP LINE OF THE LONGHAND AMOUNT"
380 PRINT"ARE AUTOMATICALLY POSITIONED FOR YOU.)"
385 PRINT"FINALLY, MARK THE OVERLAY AT THE BOTTOM"
390 PRINT"LEFT CORNER OF THE CHECK (CHECK LENGTH)."
395 PRINT" WHEN YOU ARE ALL THROUGH MARKING THE"
400 PRINT"OVERLAY, SELECT [154] MODIFY CHECK FORMAT [146]"
405 PRINT"FROM THE MENU, AND ENTER THE POSITIONS"
410 PRINT"[158] (PRESS ANY KEY TO CONTINUE)[145]":POKE198,0
415 GETAN$:IFAN$=""THEN415
420 PRINT"[147]TO BE PRINTED THAT YOU'VE MARKED ON THE"
425 PRINT"OVERLAY. SELECT [154] PRINT A SAMPLE CHECK [146]"
430 PRINT"FROM THE MENU, AND HOLD IT UP AGAINST"
435 PRINT"ONE OF YOUR CHECKS TO SEE IF YOU ARE"
440 PRINT"SATISFIED WITH THE RESULTS. IF YOU'VE"
445 PRINT"CHANGED THE LENGTH OF THE CHECK, YOU"
450 PRINT"SHOULD [154] PRINT A SAMPLE CHECK [146] TWO OR"
455 PRINT"THREE TIMES IN A ROW TO BE SURE THAT"
460 PRINT"YOUR NEW CHECK LENGTH WORKS CORRECTLY."
465 PRINT"SELECT [154] MODIFY CHECK FORMAT [146] & READJUST"
470 PRINT"THE FORMAT UNTIL YOU ARE SATISFIED."
535 PRINT"[158] (ANY KEY RETURNS TO THE MENU)[145]":POKE198,0
540 GETAN$:IFAN$=""THEN540
545 GOTO1500
550 GOTO1808
552 PRINT"[147] *** [158]PRINTING CHECK OVERLAY ***"
555 OPEN4,4
560 A$=" 1 2 3 4 "
565 B$="5 6 7"
570 C$=A$+B$:D$="+++++++++++++++++++++++++++++++++++++++":D$=D$+D$
575 E$="1234567890"
580 F$="12345678":E$=" "+E$+E$+E$+E$+E$+E$+E$+F$
585 FOR X=1TO24:G$(X)=RIGHT$(STR$(X),2)+D$:NEXTX:PRINT#4
590 PRINT#4," *** BANK ACCOUNTS CHECK PRINTING FORMAT OVERLAY ***"
595 PRINT#4
600 PRINT#4,"BE SURE THE CHECK COVERS THE +'S IN THE UPPER-LEFT OF THE OVERLAY."
605 PRINT#4,"MARK THE OVERLAY AT THE LEFT-MOST POSITION TO PRINT FOR THE DATE,"
610 PRINT#4,"NUMERIC AMOUNT, LONGHAND AMOUNT, PAYEE, AND CHECK MEMO (ACCT. #)."
615 PRINT#4,"FINALLY, MARK THE OVERLAY'S + AT THE BOTTOM-LEFT CORNER OF CHECK."
620 PRINT#4:PRINT#4,C$
625 PRINT#4,E$
630 FOR X=1TO24
635 PRINT#4,G$(X)
640 NEXTX:PRINT#4:PRINT#4
645 CLOSE4:GOTO1500
650 GOTO1808
652 PRINT"[147][154] PRINT A SAMPLE CHECK "
655 PRINT"[158] PRINT WITH OPTIONAL ADDRESS? (Y[158]/N[158])"
660 PRINT" OPTIONAL ADDRESS WILL NOT PRINT IF"
665 PRINT"THE NEXT TWO LINES UNDER THE PAYEE ARE"
670 PRINT"USED FOR ANY OF THE OTHER PRINT FIELDS."
675 GETAN$:IFAN$="Y"THENPRINT""TAB(37)AN$:GOTO690
680 IFAN$="N"THENPRINT""TAB(37)AN$:NA$="N":GOTO690
685 GOTO675
690 PRINT" *** [158]PRINTING SAMPLE CHECK ***"
695 P1$(1)="SEPTEMBER 30,1989":P1$(8)="PHONE # 1-800-328-0304"
700 P1$(3)="*** TEN THOUSAND SEVEN HUNDRED AND ***":LN$(1)="*"
705 P1$(4)="*** SEVENTY SEVEN AND 77/100 DOLLARS ***":P1$(2)="10777.77"
710 P1$(5)="DELUXE CHECK PRINTERS":P1$(6)="1275 RED FOX ROAD":LN$(NL)="*"
715 P1$(7)="ST. PAUL, MN 55164-9986":IFNA$="N"THENP1$(6)="":P1$(7)=""
720 FORX=2TONL-1:LN$(X)="":NEXTX
725 FORX=1TO8:S=LN(X,2):IFLN(X,3)=3THENS=LN(X,2)+(LEN(P1$(4))/2)-(LEN(P1$(3))/2)
730 M=LN(X,1):IFS<LN(X,2)THENS=LN(X,2)
735 IFLN$(M)<>""THEN745
740 SP$(M)=LEFT$(SP$,S-1):LN$(M)=SP$(M)+P1$(LN(X,3)):GOTO785
745 A=LEN(LN$(M))-1:IFS-A>0THEN775
750 PRINT" ERROR [146][158]-CURRENT PRINT LOCATIONS OVERLAP.":GOSUB1245
755 PRINT"SELECT [154] MODIFY CHECK FORMAT [146] & READJUST"
760 PRINT"PRINT LOCATIONS TO ELIMINATE OVERLAP.":GOSUB1245:GOSUB1245:GOSUB1245
765 GOSUB1245:GOSUB1245:IFSV$="Y"THENSV$="N"
770 GOTO1500
775 NS$(M)=LEFT$(SP$,S-A)
780 LN$(M)=LN$(M)+NS$(M)+P1$(LN(X,3))
785 NEXTX:IFSV$="Y"THEN1065
790 OPEN4,4
795 FORX=1TONL
800 PRINT#4,LN$(X)
805 NEXTX:CLOSE4:GOTO1500
810 FORX=1TO8:IFLN(X,3)=4THENI=X
815 IFLN(X,3)=5THENJ=X
820 NEXTX:X=1:AC$="":AN$=""
825 PRINT"[147][154] M O D I F Y C H E C K F O R M A T ":POKE198,0
830 PRINT"CURRENT CHECK LENGTH IS[154]"NL"LINES."
835 PRINT" (JUST PRESS RETURN [146] IF NO CHANGE)[145][145][145]"
840 INPUT"[158]HOW LONG IS YOUR CHECK [157][157][157][157][157]";AN$
845 IFAN$=""THENPRINTTAB(24)"[145]UNCHANGED":GOSUB1245:GOTO860
850 IFVAL(AN$)>24THENAN$="":PRINT"[145]":GOTO840
855 NL=VAL(AN$):AC$="1"
860 IFLN(X,3)=3THENLN(X,1)=LN(I,1)-1:LN(X,2)=LN(I,2):H=X:GOTO945
865 IFLN(X,3)=6THENLN(X,1)=LN(J,1)+1:LN(X,2)=LN(J,2):K=X:GOTO945
870 IFLN(X,3)=7THENLN(X,1)=LN(J,1)+2:LN(X,2)=LN(J,2):L=X:GOTO945
875 PRINT"[147][154] M O D I F Y C H E C K F O R M A T ":POKE198,0
880 PRINT"CURRENT LOCATION OF [158]"M$(LN(X,3))" IS:"
885 PRINT" DOWN:[154]"LN(X,1)" ACROSS:[154]"LN(X,2)
890 PRINT"ENTER NEW LOCATION OF [158]"M$(LN(X,3))":"
895 PRINT" (JUST PRESS RETURN [146] IF NO CHANGE)":AN=0
900 INPUT"[158]LINES DOWN";AN
905 IFAN=0THENPRINT"[145]UNCHANGED":GOTO920
910 IFAN>NLTHENPRINT"OUT OF RANGE":GOTO885
915 LN(X,1)=AN:AC$="1"
920 AN=0:PRINT
925 INPUT"[158]LINES ACROSS";AN
930 IFAN=0THENPRINT"[145]UNCHANGED":GOSUB1245:GOTO945
935 IFAN>71THENPRINT"OUT OF RANGE":GOTO910
940 LN(X,2)=AN:AC$="1"
945 IFX<8THENX=X+1:GOTO860
950 LN(H,1)=LN(I,1)-1:LN(H,2)=LN(I,2)
955 LN(K,1)=LN(J,1)+1:LN(L,2)=LN(J,2)
960 LN(L,1)=LN(J,1)+2:LN(L,2)=LN(J,2)
965 FORX=1TO8:IFX=KORX=LTHEN985
970 IFLN(X,1)=LN(K,1)THEN980
975 IFLN(X,1)<>LN(L,1)THEN985
980 LN(K,1)=NL+1:LN(L,1)=NL+2:X=8
985 NEXTX
990 IFAC$=""THENPRINT" *** [158]NO CHANGES MADE ***":GOSUB1245:GOTO1500
995 PRINT" *** [158]ADJUSTING CHECK FORMAT ***"
1000 AC=9:FORX=11TO18:Y=1
1005 LN(X,1)=LN(Y,1):LN(X,2)=LN(Y,2):LN(X,3)=LN(Y,3):Z=Y
1010 Y=Y+1:IFY>8THEN1035
1015 IFLN(Y,1)<LN(X,1)THEN1005
1020 IFLN(Y,1)>LN(X,1)THEN1010
1025 IFLN(Y,2)<LN(X,2)THEN1005
1030 GOTO1010
1035 LN(Z,1)=99:NEXTX
1040 FORX=1TO8:LN(X,1)=LN(X+10,1):LN(X,2)=LN(X+10,2):LN(X,3)=LN(X+10,3):NEXTX
1045 GOTO1500
1050 IFAC<>9THENPRINT" *** [158]NO CHANGES TO SAVE ***":GOSUB1245:GOTO100
1055 F=1
1060 PRINT"[147]":SV$="Y":GOTO695
1065 PRINT" *** [158]SAVING MODIFICATIONS ***"
1070 OPEN8,8,8,"@0:MOD.DATA,S,W":GOSUB1215
1072 PRINT#8,QL$:GOSUB1215
1075 PRINT#8,NL:GOSUB1215
1080 FORX=1TO8
1085 PRINT#8,LN(X,1):GOSUB1215
1090 PRINT#8,LN(X,2):GOSUB1215
1095 PRINT#8,LN(X,3):GOSUB1215
1100 NEXTX:FORX=1TO3
1105 PRINT#8,DD$(X):GOSUB1215
1110 PRINT#8,WD$(X):GOSUB1215
1111 NEXTX
1112 PRINT#8,NC(1):GOSUB1215
1113 PRINT#8,NC(2):GOSUB1215
1115 CLOSE8:AC=0:SV$="N":GOTO1350
1120 F=2
1125 IFAC=9THENGOTO1325
1130 CLOSE8:CLOSE15:POKE198,1
1135 PRINT"[147] *** [158]ONE MOMENT PLEASE ***"
1140 PRINT"[144]LOAD"CHR$(34)"MENU";
1145 PRINTCHR$(34)",8";
1150 POKE198,5:POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13:END
1160 OPEN8,8,8,"0:MOD.DATA,S,R"
1165 GOSUB1215
1167 INPUT#8,QL$:GOSUB1215
1170 INPUT#8,NL:GOSUB1215
1175 FORX=1TO8
1180 INPUT#8,LN(X,1):GOSUB1215
1185 INPUT#8,LN(X,2):GOSUB1215
1190 INPUT#8,LN(X,3):GOSUB1215
1195 NEXTX:FORX=1TO3
1200 INPUT#8,DD$(X):GOSUB1215
1205 INPUT#8,WD$(X):GOSUB1215
1210 NEXTX
1211 INPUT#8,NC(1):GOSUB1215
1212 INPUT#8,NC(2):GOSUB1215
1213 CLOSE8:RETURN
1215 INPUT#15,EN,EM$,ET,ES
1220 IFEN=0THENRETURN
1225 PRINT" [159]DISK [159]OPERATING [159]SYSTEM ERROR #"EN"[157] [146]":END
1245 FORT=1TO500:NEXTT:RETURN
1250 FORX=1TO3
1255 PRINT"[147][154] MODIFY DEFAULT PROMPTS [146]"
1260 PRINT"CURRENT MEMO DEFAULT FOR DEPOSITS TO"
1265 IFX=3THENPRINT"THE [158]SAVINGS ACCOUNT IS: [154]"DD$(X):GOTO1275
1270 PRINT"[158]CHECKING ACCOUNT #"X" IS: [154]"DD$(X)
1275 PRINT"NEW DEFAULT [154]"DD$(X):AN$="":INPUT"[145]";AN$
1280 IFAN$=DD$(X)THEN1290
1285 DD$(X)=AN$:AC=9
1290 PRINT"CURRENT MEMO DEFAULT FOR WITHDRAWALS TO"
1295 IFX=3THENPRINT"THE [158]SAVINGS ACCOUNT IS: [154]"WD$(X):GOTO1305
1300 PRINT"[158]CHECKING ACCOUNT #"X" IS: [154]"WD$(X)
1305 PRINT"NEW DEFAULT [154]"WD$(X):AN$="":INPUT"[145]";AN$
1310 IFAN$=WD$(X)THEN1320
1315 WD$(X)=AN$:AC=9
1320 NEXTX:GOTO35
1325 PRINT"[147][158]SAVE MODIFICATIONS BEFORE LEAVING? (Y[158]/N[158])"
1330 GETAN$:IFAN$=""THEN1330
1335 IFAN$="N"THEN1350
1340 IFAN$<>"Y"THEN1330
1345 GOTO1060
1350 IFF=2THEN1130
1360 GOTO100
1365 OPEN8,8,8,"MO.BILLS 3,S,R"
1370 GOSUB1215
1375 INPUT#8,PW$
1380 GOSUB1215
1385 CLOSE8
1395 E=1:IFPW$="DISABLED"THENRETURN
1400 PRINTMT$
1405 PRINT"[158] PLEASE ENTER YOUR PASSWORD,"
1410 INPUT"[158] THEN PRESS RETURN [146][144]";P$
1415 IFP$=PW$THENRETURN
1420 IF E=3THENSYS64738
1425 PRINTTAB(10)" INVALID PASSWORD.":PRINTTAB(10)" TYPE CAREFULLY. "
1430 E=E+1:FORT=1TO999:NEXTT:GOTO1400
1435 PRINT"[147][154] C H A N G E P A S S W O R D "
1445 PRINT" ENTER 'DISABLED' IF YOU DON'T WANT"
1450 PRINT" TO USE THE PASSWORD ENTRY ROUTINE."
1451 PRINT" (IF YOU SHOULD HAPPEN TO FORGET YOUR"
1452 PRINT" PASSWORD,READ THE FILE [154]";CHR$(34);"MO.BILLS 3";CHR$(34);")"
1455 PRINT"[158] CURRENT PASSWORD IS: ";PW$
1460 INPUT"[158] ENTER DESIRED PASSWORD:";PW$
1465 OPEN8,8,8,"@0:MO.BILLS 3,S,W"
1470 GOSUB1215:PRINT#8,PW$;CHR$(13):GOSUB1215:CLOSE8
1475 IFPW$="DISABLED"THENPRINT" PASSWORD ROUTINE IS NOW DISABLED.":GOTO1495
1480 PRINT" YOUR NEW PASSWORD HAS BEEN RECORDED."
1495 FOR T=1TO999:NEXTT:GOTO35
1500 PRINT"[147][154] MODIFY CHECKPRINTING "
1505 SL$(1)=" INSTRUCTIONS "
1510 SL$(2)=" PRINT AN OVERLAY PATTERN "
1515 SL$(3)=" PRINT A SAMPLE CHECK "
1520 SL$(4)=" MODIFY CHECK FORMAT "
1525 SL$(5)=" RETURN TO MENU "
1530 C1$="":C2$="[154]":C3$="[145][145][145][145][145][145][145][145][145]":C4$="":C5$="":MN=5
1535 MU=2:GOTO110
1540 ONANGOTO215,550,650,810,35
1600 IFQL$="N"THENQL$="Y":AC=9:GOTO35
1605 QL$="N":AC=9:GOTO35
1610 PRINT"[147] [154] CHECKPRINTING ON/OFF "
1615 PRINT" IF YOU DO NOT WISH TO USING THE"
1620 PRINT" CHECKPRINTING FEATURE OF THE PROGRAM,"
1625 PRINT" YOU MAY AVOID AUTOMATICALLY GOING TO"
1630 PRINT" THE CHECKPRINTING MENU AFTER ENTERING"
1635 PRINT" A CHECK BY TURNING THE CHECKPRINTING"
1640 PRINT" OFF FOR THAT ACCOUNT."
1645 PRINT"[158] CURRENT CHECKPRINT STATUS :"
1650 PRINT" CHECKING ACCOUNT #1: ";
1655 IFNC(1)=0THENPRINT"[154]ON":GOTO1665
1660 PRINT"[154]OFF"
1665 PRINT" CHECKING ACCOUNT #2: ";
1670 IFNC(2)=0THENPRINT"[154]ON":GOTO1680
1675 PRINT"[154]OFF"
1680 PRINT"[158] CHANGE CURRENT STATUS? (Y[158]/N[158])";
1685 GETAN$:IFAN$=""THEN1685
1690 IFAN$="N"THEN35
1695 IFAN$<>"Y"THEN1685
1700 AC=9:PRINT" Y":PRINT"[158] CHANGE WHICH ACCOUNT? (1[158]/2[158])"
1705 GETAN$:IFAN$=""THEN1705
1710 IFAN$="2"THEN1730
1715 IFAN$<>"1"THEN1705
1720 IFNC(1)=0THENNC(1)=1:GOTO1610
1725 NC(1)=0:GOTO1610
1730 IFNC(2)=0THENNC(2)=1:GOTO1610
1735 NC(2)=0:GOTO1610
1808 IFPC=1THEN1824
1810 PRINT"[147][154]PLEASE BE SURE YOUR PRINTER IS TURNED ON[146]"
1812 PRINT"[158] PRESS RETURN [146][158] TO PROCEED,"
1814 PRINT"[158] OR PRESS 'C[158]' TO CANCEL PRINTING"
1818 GETAN$:IFAN$=CHR$(13)THENPC=1:GOTO1824
1820 IFAN$="C"THEN1500
1822 GOTO1818
1824 IFAN=2THEN552
1826 GOTO652